***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 01, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJGBLC24C 1 2 
.param
+vc0 = 6.202e-9		 vc1 = 3.116e-10	 vc2 = -4.243e-12		
+tc1 = 1.208e-1		 tc2 = 4.155e-2
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1)+vc2*v(c,1)*v(c,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2)+vc2*v(c,2)*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1   
***** dc model parameter *****
+ is = 1e-13		   n = 0.8		  rs = 1e-2
+ibv = 1e-3		 nbv = 5		  bv = 28.005
***** capacitance parameter *****
+cjo = 8.796e-13	   m = 2.133e-2		  vj = 8.672e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.105		 xti = 3
+trs1 = 1e-4		tbv1 = 8.658e-4
.ends PJGBLC24C
*$
